Эффект Иней (разброс)

Delphi , Графика и Игры , Bitmap

Автор: Fenik
WEB-сайт: http://delphibase.endimus.com

{ **** UBPFD *********** by delphibase.endimus.com ****
>> Эффект 'Иней' (разброс)

Зависимости: Classes, Graphics
Автор:       Fenik, chook_nu@uraltc.ru, Новоуральск
Copyright:   Собственное написание (Николай федоровских)
Дата:        1 июня 2002 г.
***************************************************** }

procedure Disorder(Bitmap: TBitmap; Hor, Ver: Integer; BackColor: TColor);

  function RandomInRadius(Num, Radius: Integer): Integer;
  begin
    if Random(2) = 0 then
      Result := Num + Random(Radius)
    else
      Result := Num - Random(Radius);
  end;

type
  TRGB = record
    B, G, R: Byte;
  end;
  pRGB = ^TRGB;
var
  x, y, WW, HH, xr, yr: Integer;
  Dest1, Dest2, Src1, Src2: PRGB;
  Bmp: TBitmap;
begin
  Randomize;
  Bitmap.PixelFormat := pf24Bit;
  Bmp := TBitmap.Create;
  try
    Bmp.Assign(Bitmap);
    WW := Bitmap.Width - 1;
    HH := Bitmap.Height - 1;
    Bitmap.Canvas.Brush.Color := BackColor;
    Bitmap.Canvas.FillRect(Rect(0, 0, WW + 1, HH + 1));
    for y := 0 to HH do
    begin
      for x := 0 to WW do
      begin
        xr := RandomInRadius(x, Hor);
        yr := RandomInRadius(y, Ver);
        if (xr >= 0) and (xr < WW) and (yr >= 0) and (yr < HH) then
        begin
          Src1 := Bmp.ScanLine[y];
          Src2 := Bmp.ScanLine[yr];
          Dest1 := Bitmap.ScanLine[y];
          Dest2 := Bitmap.ScanLine[yr];
          Inc(Src1, x);
          Inc(Src2, xr);
          Inc(Dest1, x);
          Inc(Dest2, xr);
          Dest1^ := Src2^;
          Dest2^ := Src1^;
        end;
      end;
    end;
  finally
    Bmp.Free;
  end;
end;

Пример использования:

Disorder(FBitmap, 5, 5, clWhite); 

Это фрагмент кода на Delphi, который реализует эффект "Iney" или "Disorder", случайно перемешивающий пиксели в указанном радиусе от их оригинальных позиций. Эффект может использоваться для создания интересных и уникальных визуальных паттернов.

Расшифровка кода:

• Процедура Disorder принимает три параметра: Bitmap, Hor и Ver, где:
  • Bitmap - целевой битовик, к которому будет применен эффект.
  • Hor и Ver - горизонтальный и вертикальный радиусы соответственно, в которых пиксели будут случайно перемешиваться.
  • BackColor - цвет, используемый для заливки фона битовика.
• Код использует тип записи TRGB, представляющий RGB-пиксель с полями для компонентов синего, зеленого и красного цветов.
• Процедура создает временный битовик Bmp и присваивает ему значение из оригинального Bitmap. Затем она настраивает кисть канваса на указанный BackColor и заливает всю картинку этим цветом.
• Код проходит через каждый пиксель в битовике, используя два вложенных цикла for. Для каждого пикселя он генерирует случайные координаты x и y в указанном радиусе с помощью функции RandomInRadius.
• Если сгенерированные координаты находятся в допустимом диапазоне (т.е., не выходят за пределы), код обменивает значения пикселей между оригинальной и перемешанной позициями.
• Наконец, процедура освобождает временный битовик Bmp.

Пример использования в конце демонстрирует, как применить этот эффект к битовiku, с FBitmap как целевым битовиком, 5 как горизонтальным радиусом, 5 как вертикальным радиусом и clWhite как цветом фона.

В целом, это код обеспечивает интересный визуальный эффект, который может быть использован в различных приложениях, таких как обработка графики или разработка игр.

В статье описывается алгоритм 'Эффект Иней' (разброс), позволяющий создавать эффект разброса пикселей на изображении с использованием языка программирования Delphi.

Комментарии и вопросы

Получайте свежие новости и обновления по Object Pascal, Delphi и Lazarus прямо в свой смартфон. Подпишитесь на наш Telegram-канал delphi_kansoftware и будьте в курсе последних тенденций в разработке под Linux, Windows, Android и iOS

:: Главная :: Bitmap ::