3D-рамка для текстовых компонентов

Delphi , Компоненты и Классы , TLabel

Один из примеров создания текстового компонента с трехмерной декоративной контурной рамкой (для создания компонента потребовалось около получаса. Он демонстрирует только принцип получения рамки. Я не стал колдовать над свойствами типа ParentFont..., т.к. это заняло бы еще немало времени и места).

unit IDSLabel;

interface

uses

  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms,
  Dialogs,

  ExtCtrls;

type

  TIDSLabel = class(TBevel)
  private
    { Private declarations }
    FAlignment: TAlignment;
    FCaption: string;
    FFont: TFont;
    FOffset: Byte;

    FOnChange: TNotifyEvent;

    procedure SetAlignment(taIn: TAlignment);
    procedure SetCaption(const strIn: string);
    procedure SetFont(fntNew: TFont);
    procedure SetOffset(bOffNew: Byte);
  protected
    { Protected declarations }
    constructor Create(compOwn: TComponent); override;
    destructor Destroy; override;
    procedure Paint; override;
  public
    { Public declarations }
  published
    { Published declarations }
    property Alignment: TAlignment read FAlignment write SetAlignment default
      taLeftJustify;
    property Caption: string read FCaption write SetCaption;
    property Font: TFont read FFont write SetFont;
    property Offset: Byte read FOffset write SetOffset;

    property OnChange: TNotifyEvent read FOnChange write FOnChange;
  end;

implementation

constructor TIDSLabel.Create;
begin

  inherited Create(compOwn);

  FFont := TFont.Create;
  with compOwn as TForm do
    FFont.Assign(Font);

  Offset := 4;
  Height := 15;
end;

destructor TIDSLabel.Destroy;
begin

  FFont.Free;

  inherited Destroy;
end;

procedure TIDSLabel.Paint;
var

  wXPos, wYPos: Word;
begin

  {Рисуем рамку}
  inherited Paint;

  {Назначаем шрифт}
  Canvas.Font.Assign(Font);

  {Вычисляем вертикальную позицию}
  wYPos := (Height - Canvas.TextHeight(Caption)) div 2;

  {Вычисляем горизонтальную позицию}
  wXPos := Offset;
  case Alignment of
    taRightJustify: wXPos := Width - Canvas.TextWidth(Caption) - Offset;
    taCenter: wXPos := (Width - Canvas.TextWidth(Caption)) div 2;
  end;
  Canvas.Brush := Parent.Brush;
  Canvas.TextOut(wXPos, wYPos, Caption);

end;

procedure TIDSLabel.SetAlignment;
begin

  FAlignment := taIn;
  Invalidate;
end;

procedure TIDSLabel.SetCaption;
begin
  FCaption := strIn;

  if Assigned(FOnChange) then
    FOnChange(Self);

  Invalidate;
end;

procedure TIDSLabel.SetFont;
begin

  FFont.Assign(fntNew);
  Invalidate;
end;

procedure TIDSLabel.SetOffset;
begin

  FOffset := bOffNew;
  Invalidate;
end;

end.

Это компонент VCL Delphi, конкретно - пользовательский контроль, который наследуется от TBevel и предоставляет дополнительные свойства и методы для создания текстового лейбла с трехмерной декоративной рамкой.

Разбор кода:

Декларация модуля

Модуль декларирует компонент IDSLabel, который является классом, наследуемым от TBevel. Клауза uses импортирует различные модули VCL, включая Windows, Graphics и Controls.

Типовая декларация

Типовая декларация TIDSLabel определяет свойства и методы пользовательского контроля. Она включает:

• Приватные поля: FAlignment, FCaption, FFont и FOffset, которые хранят значения выравнивания, надписи, шрифта и смещения соответственно.
• Публичные свойства: Alignment, Caption, Font и Offset, которые позволяют доступ к этим приватным полям.
• Защищенные методы: constructor Create и destructor Destroy, которые перезаписаны из базового класса.
• Опубликованные события: OnChange, которое является уведомляющим событием, которое происходит при изменении надписи.

Имплементация

Секция имплементации определяет методы и конструкторы для пользовательского контроля. Основные методы:

• Create: Инициализирует компонент, настраивает шрифт и присваивает его родительскому форму.
• Destroy: Освобождает объект шрифта.
• Paint: Рисует надпись с трехмерной рамкой. Он рассчитывает вертикальные и горизонтальные позиции текста в зависимости от свойства выравнивания и длины надписи.

Другие методы (SetAlignment, SetCaption, SetFont и SetOffset) обновляют соответствующие приватные поля и инвалидируют контроль, чтобы вызвать перерисовку.

Замечания

• Код довольно простой, но создание пользовательского VCL-компонента требует хорошего понимания объектно-ориентированного программирования Delphi и фреймворка VCL.
• Код использует некоторые advanced функции, такие как события свойств (OnChange) и управление шрифтами. Подробное объяснение этих концепций было бы полезно для новых разработчиков.
• Как упоминает автор, процесс создания занял около 30 минут, что является хорошим признаком того, что создание пользовательских контролов может быть временем- и ресурсоемким, но вознаграждающимся.

В статье описывается пример создания текстового компонента с трехмерной декоративной контурной рамкой в дельфии.

Комментарии и вопросы

Получайте свежие новости и обновления по Object Pascal, Delphi и Lazarus прямо в свой смартфон. Подпишитесь на наш Telegram-канал delphi_kansoftware и будьте в курсе последних тенденций в разработке под Linux, Windows, Android и iOS

:: Главная :: TLabel ::