Добавление шума в изображение

Delphi , Графика и Игры , Bitmap

Автор: Fenik
WEB-сайт: http://delphibase.endimus.com

{ **** UBPFD *********** by delphibase.endimus.com ****
>> Добавление шума в изображение

Зависимости: Graphics
Автор:       Fenik, chook_nu@uraltc.ru, Новоуральск
Copyright:   Автор Федоровских Николай
Дата:        5 июня 2002 г.
***************************************************** }

procedure AddNoise(Bitmap: TBitmap; Amount: Integer; Mono: Boolean);
{Если Mono = False, то точки цветные, иначе - чёрно-белые.
 Процедура взята из библиотеки FastLIB и немного переделана}

  function BLimit(B: Integer): Byte;
  begin
    if B < 0 then
      Result := 0
    else if B > 255 then
      Result := 255
    else
      Result := B;
  end;

type
  TRGB = record
    B, G, R: Byte;
  end;
  pRGB = ^TRGB;
var
  x, y, i, a: Integer;
  Dest: pRGB;
begin
  Bitmap.PixelFormat := pf24Bit;
  Randomize;
  i := Amount shr 1;
  if Mono then
    for y := 0 to Bitmap.Height - 1 do
    begin
      Dest := Bitmap.ScanLine[y];
      for x := 0 to Bitmap.Width - 1 do
      begin
        a := Random(Amount) - i;
        with Dest^ do
        begin
          r := BLimit(r + a);
          g := BLimit(g + a);
          b := BLimit(b + a);
        end;
        Inc(Dest);
      end;
    end
  else
    for y := 0 to Bitmap.Height - 1 do
    begin
      Dest := Bitmap.ScanLine[y];
      for x := 0 to Bitmap.Width - 1 do
      begin
        with Dest^ do
        begin
          r := BLimit(r + Random(Amount) - i);
          g := BLimit(g + Random(Amount) - i);
          b := BLimit(b + Random(Amount) - i);
        end;
        Inc(Dest);
      end;
    end;
end;

Пример использования:

AddNoise(FBitmap, 65, False); 

Программный код на Delphi для добавления шума в изображение. Процедура AddNoise принимает три параметра:

• Bitmap: изображение, к которому нужно добавить шум
• Amount: количество шума (целочисленное значение)
• Mono: логическое флаг, указывающее, использовать ли монохромный шум (черно-белый) или цветной

Код использует модуль Graphics и определяет два типа: TRGB для 24-разрядных RGB-значений и pRGB как указатель на TRGB.

Процедура сначала устанавливает формат пикселей в изображении в 24-разрядный. Затем она случайно генерирует значение i на основе параметра Amount.

Если Mono истинно (то есть монохромный шум), код проходит по каждой строке изображения, а затем по каждому пикселю в этой строке, и добавляет случайное значение между -i и i к компонентам красного, зеленого и синего цветов. Результаты ограничиваются диапазоном 0-255 с помощью функции BLimit.

Если Mono ложно (то есть цветной шум), код делает то же самое, но использует расчет Random(Amount) - i для каждого компонента цвета отдельно.

Конечный результат - изображение с добавленным шумом.

Некоторые предложения по улучшению:

• Вместо использования глобального вызова Randomize в начале процедурыconsider passing a random seed as a parameter to allow for more control over the noise generation.
• Вы можете рассмотреть возможность добавления опций для различных типов шума (например, Гауссового, соль и перец и т.д.) или для контроля частоты и амплитуды шума.
• Если вы планируете использовать этот код в приложении с высокими требованиями к производительности, вам может потребоваться более эффективный алгоритм генерации случайных значений.

Альтернативное решение - использовать библиотеку для обработки изображений, которая предоставляет встроенные функции для генерации шума. Это будет, вероятно, более эффективно и проще в использовании, чем написание собственного.custom implementation от scratch.

Добавление шума в изображение - процедура на языке Delphi, которая генерирует случайные изменения оттенков цвета пикселей в изображении.

Комментарии и вопросы

Получайте свежие новости и обновления по Object Pascal, Delphi и Lazarus прямо в свой смартфон. Подпишитесь на наш Telegram-канал delphi_kansoftware и будьте в курсе последних тенденций в разработке под Linux, Windows, Android и iOS

:: Главная :: Bitmap ::