Эффект Волны (синусоидальные, вид сбоку)

Delphi , Графика и Игры , Bitmap

Автор: Fenik
WEB-сайт: http://delphibase.endimus.com

{ **** UBPFD *********** by delphibase.endimus.com ****
>> Эффект 'Волны' (синусоидальные, вид сбоку)

Зависимости: Classes, Graphics
Автор:       Fenik, chook_nu@uraltc.ru, Новоуральск
Copyright:   Собственное написание (Николай федоровских)
Дата:        1 июня 2002 г.
***************************************************** }

procedure WaveSin(Bitmap: TBitmap; Frequency, Length:
  Integer; Hor: Boolean; BackColor: TColor);

  function Min(A, B: Integer): Integer;
  begin
    if A < B then
      Result := A
    else
      Result := B;
  end;

  function Max(A, B: Integer): Integer;
  begin
    if A > B then
      Result := A
    else
      Result := B;
  end;

const
  Rad = Pi / 180;
type
  TRGB = record
    B, G, R: Byte;
  end;
  pRGB = ^TRGB;
var
  x, y, f: Integer;
  Dest, Src: pRGB;
  Bmp: TBitmap;
begin
  Bitmap.PixelFormat := pf24Bit;
  Bmp := TBitmap.create;
  try
    Bmp.Assign(Bitmap);
    Bitmap.Canvas.Brush.Color := BackColor;
    Bitmap.Canvas.FillRect(Rect(0, 0, Bitmap.Width, Bitmap.Height));
    for y := 0 to Bmp.Height - 1 do
    begin
      Src := Bmp.ScanLine[y];
      for x := 0 to Bmp.Width - 1 do
      begin
        if Hor then
        begin
          f := Min(Max(Round(Sin(x * Rad * Length) * Frequency) + y, 0),
            Bitmap.Height - 1);
          Dest := Bitmap.ScanLine[f];
          Inc(Dest, x);
        end
        else
        begin
          f := Min(Max(Round(Sin(y * Rad * Length) * Frequency) + x, 0),
            Bitmap.Width - 1);
          Dest := Bitmap.ScanLine[y];
          Inc(Dest, f);
        end;
        Dest^ := Src^;
        Inc(Src);
      end;
    end;
  finally
    Bmp.free;
  end;
end;

Пример использования:

WaveSin(FBitmap, FBitmap.Width div 50, FBitmap.Width div 40, True, clWhite); 

Программный код на языке Delphi для создания эффекта "Волна" (Wave), который представляет собой синусоидальную волну, видимую с боку. Функция WaveSin принимает четыре параметра: Bitmap, Frequency, Length, и Hor. Она рисует волну на указанной картинке, частоту и длину которой определяются входными значениями.

Разбивка кода:

1. Первая секция - заголовок, содержащий информацию о авторе, правах и дате создания.
2. Процедура WaveSin принимает четыре параметра: Bitmap, Frequency, Length, и Hor. Она использует эти параметры для рисования волн на картинке.
3. Функции Min и Max используются для расчета минимальной и максимальной значений координаты x волны.
4. Код затем устанавливает некоторые константы, типы и переменные.
5. Процедура WaveSin реализуется с помощью цикла, который проходит по каждому пикселю в картинке. Для каждого пикселя она рассчитывает координату y волны на основе функции синуса, а затем устанавливает цвет пикселя соответствующим значением из волны.
6. Если Hor истинно, то координата x используется как вход для функции синуса; иначе, координата y.
7. Код также устанавливает цвет кисти в указанный BackColor, заливает картинку этим цветом и затем сохраняет полученный образец.

Пример использования в конце кода показывает, как использовать эту процедуру для создания волны на картинке:

WaveSin(FBitmap, FBitmap.Width div 50, FBitmap.Width div 40, True, clWhite);

Это рисует волну на FBitmap с частотой FBitmap.Width div 50, длиной FBitmap.Width div 40 и фоном белым.

В целом, этот код предоставляет простой способ создания синусоидальных волн в Delphi.

В статье описывается алгоритм создания эффекта волны на изображении с использованием синусоидальных функций и методом растеризации.

Комментарии и вопросы

Получайте свежие новости и обновления по Object Pascal, Delphi и Lazarus прямо в свой смартфон. Подпишитесь на наш Telegram-канал delphi_kansoftware и будьте в курсе последних тенденций в разработке под Linux, Windows, Android и iOS

:: Главная :: Bitmap ::